Новости IT

[• derminator]

Скрипты для чистки домашнего каталога пользователя
bat и sh командные файлы для автоматической чистки мусора

Собственно задача обозначена в заголовке темы. Очень интересно, кто какие командные файлы использует для автоматической очистки нежелательных файлов в домашнем каталоге пользователя.

Если есть какие-то интересные наработки, буду рад ознакомиться.

От себя пока выложу bash-скрипт для Linux Ubuntu и Debian. В других линуксах не проверял.

Исходный код

#!/bin/bash
# Чистим кеш и историю браузеров
find ~ *|\
egrep "([Cc][Aa][Cc][Hh][Ee]|[Ss][Tt][Oo][Rr]|[Cc][Oo][Oo][Kk][Ii])"|\
egrep "([Cc][Hh][Rr][Oo][Mm]|[Ff][Ii][Rr][Ee][Ff]|[Oo][Pp][Ee][Rr][Aa]|[Bb][Rr][Oo][Ww][Ss])"|\
while read fn
do
 echo $fn
 rm -R -f "$fn"
done
# Чистим разный другой мусор
find ~ -iname *thumbnails* -exec rm -R -f {} \;
find ~ -iname *trash* -exec rm -R -f {} \;
find ~ -iname .bash_history -exec rm -R -f {} \;
echo shutdown -P +30 > ~/.bash_history
rm -R -f ~/Загрузки/*
rm -R -f ~/Downloads/*

[• yozzik]

... Очень интересно, кто какие командные файлы использует для автоматической очистки нежелательных файлов в домашнем каталоге пользователя.

Если есть какие-то интересные наработки, буду рад ознакомиться. ...

Видел в интернетах батник для винды

Универсальный чистильщик кэша/истории браузеров для всех профилей

Исходный код

@echo off
setLocal EnableExtensions
mode con: cols=71 lines=30
color 1B

call :USERTEMP
call :BROWSERS
>nul pause
exit /b


:USERTEMP
echo.Очистка временных директорий для всех пользователей:
<nul set /p "T=Пользователи: "
for /f "delims=" %%a in ('dir /b /ad-h "%userprofile%\..\*"^|findstr/ixvc:"All Users" /c:"Public"') do (
   set N=0
   call :ECHO "%%~a " 1F
   call :USERTEMPMAIN "\..\%%a"
   if "!N!" GTR "0" (call :ECHO "Done   " 1A) else (call :ECHO "Empty  " 1E)
   set N=
)
echo.&echo.
exit /b

:USERTEMPMAIN
for %%a in (
"%userprofile%%~1\AppData\Local\TEMP"
"%userprofile%%~1\AppData\Local\Microsoft\Feeds Cache"
"%userprofile%%~1\AppData\Local\Microsoft\Windows\Caches"
"%userprofile%%~1\AppData\Local\Microsoft\Windows\Explorer"
"%userprofile%%~1\AppData\Local\Microsoft\Windows\WER"
"%userprofile%%~1\AppData\Local\Steam\htmlcache"
"%userprofile%%~1\AppData\Roaming\Macromedia\Flash Player"
) do (call :EMPTD "%%~a")
exit /b


:BROWSERS
echo.Очистка кешей установленных браузеров для всех пользователей:
<nul set /p "T=Пользователи: "

for /f "delims=" %%a in ('dir /b /ad-h "%userprofile%\..\*"^|findstr/ixvc:"All Users" /c:"Public"') do (
   set N=0
   call :ECHO "%%~a " 1F
   call :BROWSERSMAIN "\..\%%a"
   if "!N!" GTR "0" (call :ECHO "Done   " 1A) else (call :ECHO "Empty  " 1E)
   set N=
)
echo.&echo.
exit /b

:BROWSERSMAIN
(
REM Internet Explorer

taskkill /f /im iexplore.exe
if "%1"=="" start /wait "" RunDll32 InetCpl.cpl,ClearMyTracksByProcess 8

for %%a in (
"%userprofile%%~1\AppData\Local\Microsoft\Windows\Temporary Internet Files"
"%userprofile%%~1\AppData\Local\Microsoft\Windows\WebCache"
"%userprofile%%~1\AppData\Local\Microsoft\Windows\WebCache.old"
) do (
   call :EMPTD "%%~a"
)


REM Firefox
if exist "%userprofile%%~1\AppData\Roaming\Mozilla\Firefox\profiles.ini" (
   taskkill /f /im firefox.exe
   for /f "tokens=2 delims=/" %%a in (
       'type "%userprofile%%~1\AppData\Roaming\Mozilla\Firefox\profiles.ini" ^|find /i "Path="'
   ) do (
   call :EMPTD "%userprofile%%~1\AppData\Local\Mozilla\Firefox\Profiles\%%~a\Cache"
   ))


REM Palemoon
if exist "%userprofile%%~1\AppData\Roaming\Moonchild Productions\Pale Moon\profiles.ini" (
   taskkill /f /im palemoon.exe
   for /f "tokens=2 delims=/" %%a in (
       'type "%userprofile%%~1\AppData\Roaming\Moonchild Productions\Pale Moon\profiles.ini" ^|find /i "Path="'
   ) do (
   call :EMPTD "%userprofile%%~1\AppData\Local\Moonchild Productions\Pale Moon\Profiles\%%~a\Cache"
   ))


REM Chromium
if exist "%userprofile%%~1\AppData\Local\Chromium\User Data" (
   taskkill /f /im chrome.exe

   call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\Default\Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\Default\GPUCache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\Default\Media Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\Default\Pepper Data"

   for /f "delims=" %%d in ('dir /b /ad "%userprofile%%~1\AppData\Local\Chromium\User Data\Profile*"') do (
       call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\%%d\Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\%%d\GPUCache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\%%d\Media Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Chromium\User Data\%%d\Pepper Data"
   ))


REM Google Chrome
if exist "%userprofile%%~1\AppData\Local\Google\Chrome\User Data" (
   taskkill /f /im chrome.exe

   call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\Default\Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\Default\GPUCache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\Default\Media Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\Default\Pepper Data"

   call :EMPTD "%userprofile%%~1\AppData\Local\Google\CrashReports"

   for /f "delims=" %%d in ('dir /b /ad "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\Profile*"') do (
       call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\%%d\Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\%%d\GPUCache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\%%d\Media Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Google\Chrome\User Data\%%d\Pepper Data"
   ))


REM Opera Presto & Blink
if exist "%userprofile%%~1\AppData\Local\Opera" (
   taskkill /f /im opera.exe
   call :EMPTD "%userprofile%%~1\AppData\Local\Opera\opera x64\cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Opera\opera\cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Opera Software\Opera Stable\Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Opera Software\Opera Next\Cache"
   )


REM Yandex Browser
if exist "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data" (
   taskkill /f /im browser.exe

   call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\Default\Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\Default\GPUCache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\Default\Media Cache"
   call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\Default\Pepper Data"

   for /f "delims=" %%d in ('dir /b /ad "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\Profile*"') do (
       call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\%%d\Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\%%d\GPUCache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\%%d\Media Cache"
       call :EMPTD "%userprofile%%~1\AppData\Local\Yandex\YandexBrowser\User Data\%%d\Pepper Data"
   ))

)2>nul 1>&2
exit /b


:EMPTD
if exist "%~1" for /f "usebackq" %%f in (`dir "%~1" /b /a:`) do set "EMPTD=1"

if defined EMPTD (
   pushd "%~1" || exit /b
   rd /s /q "%~1"
   set /a N+=1
   popd
)2>nul 1>&2

set "EMPTD="
exit /b


:ECHO
for /f %%i in ('"prompt $h& for %%i in (.) do rem"') do (set Z=%%i)
pushd "%TEMP%" && (
   <nul>"%~1^" set /p="%Z%%Z%  %Z%%Z%"
   findstr /a:%2 . "%~1^*"
   del "%~1^"
   popd
   )
exit /b

Источник: cyberforum.ru/cmd-bat/thread1715023.html

--------------------

«Когда вы говорите «мне нечего скрывать», вы говорите «меня не волнует мое право на интернет-безопасность, я согласен с тем, что за мной следят». Эдвард Сноуден

[• Изабель Х]

Так, расскажите девушке, почему мне не использовать к примеру сиклинер а написанные любителями скрипты?

[• derminator]

Так, расскажите девушке, почему мне не использовать к примеру сиклинер а написанные любителями скрипты?

CCleaner — зверушка забавная и безусловно полезная, но муторно каждый раз запускать её для очистки профиля. Человеческий фактор никто не отменял: где-то забыл, где-то поленился, а в результате, кто-то сильно любопытный занялся изучением компьютерных следов.

Скрипты же можно ставить в автозапуск или привязывать к значкам на рабочем столе. Особенно использование скриптов оправданно при остром дефиците времени.

[• Edward Joseph Snowden]

CCleaner  — зверушка забавная и безусловно полезная, но муторно каждый раз запускать её для очистки профиля. Человеческий фактор никто не отменял: где-то забыл, где-то поленился, а в результате, кто-то сильно любопытный  занялся изучением компьютерных следов.

How To Use: CCleaner /AUTO /SHUTDOWN

Requirements:
CCleaner v2.10.618, or newer.

Create a new shortcut with this in it (or the path where you have CCleaner installed):

Исходный код

"C:\Program Files\CCleaner\CCleaner.exe" /AUTO /SHUTDOWN

The x64/64-bit version could look like this:

Исходный код

"C:\Program Files\CCleaner\CCleaner64.exe" /AUTO /SHUTDOWN

What It Does:
1. Allows CCleaner to automatically clean your already user pre-selected items in the Cleaner section.
2. Automatically shutdown your PC.

Note:
There's no countdown timer, and it will shut down your PC immediately after CCleaner finishes.


--------------------

For your peace of mind, use TOR Browser or TAILS.

[• Изабель Х]

CCleaner  — зверушка забавная и безусловно полезная, но муторно каждый раз запускать её для очистки профиля. Человеческий фактор никто не отменял: где-то забыл, где-то поленился, а в результате, кто-то сильно любопытный  занялся изучением компьютерных следов.

Скрипты же можно ставить в автозапуск или привязывать к значкам на рабочем столе. Особенно использование скриптов оправданно при остром дефиците времени.

Там таймер который сам запускает скан и чистку

[• yozzik]

Там таймер который сам запускает скан и чистку

Век живи — век учись. В бесплатной версии есть такая опция?
PS Не сочтите идиотом. Просто винды под рукой в данный момент нет, чтоб интерфейс программы поковырять.


--------------------

«Когда вы говорите «мне нечего скрывать», вы говорите «меня не волнует мое право на интернет-безопасность, я согласен с тем, что за мной следят». Эдвард Сноуден

[• Изабель Х]

Век живи — век учись. В бесплатной версии есть такая опция?
PS Не сочтите идиотом. Просто винды под рукой в данный момент нет, чтоб интерфейс программы поковырять.

Не в курсе, у меня профешнл крякнутый

[• с приветом]

Так, расскажите девушке, почему мне не использовать к примеру сиклинер а написанные любителями скрипты?

Яндекс.Браузер - есть такая беда в России. Сиклинер его не чистит.

--------------------

А чё это вы тут делаете?

[• Изабель Х]

Яндекс.Браузер - есть такая беда в России. Сиклинер его не чистит.

Надеюсь Вы им не пользуетесь?

[• с приветом]

Надеюсь Вы им не пользуетесь? 

Вредоносное ПО от компании Яндекс я не использую)) Только Chrome и Firefox, и только с молитвой. Точнее с ключами, которые добавляю в ярлыки браузера

C:\path\to\chrome.exe –incognito
или
C:\path\to\firefox.exe –private

Плюс оба браузера долго ковыряю на предмет настроек безопасности. Их там есть.

А вообще, по теме полезно почитать статью Дениса Колисниченко "Заметаем следы. Как заставить Windows удалить историю, логи, кеши и все забыть" Ссылка: https://xakep.ru/2016/05/05/windows-delete-history/




--------------------

А чё это вы тут делаете?

[• derminator]

А вообще, по теме полезно почитать статью Дениса Колисниченко "Заметаем следы. Как заставить Windows удалить историю, логи, кеши и все забыть"  Ссылка: https://xakep.ru/2016/05/05/windows-delete-history/

Винрарный автор! См. также книгу Дениса Колисниченко "Анонимность и безопасность в Интернете". https://clck.ru/Vd43U

У Колисниченко есть 5 годных книг по безопасности.

[• Диляра Белочкина]

Не скрипт, конечно, но...

Ярлык рабочего стола "Выключить компьютер"

Исходный код

cmd /c rmdir /s /q  %userprofile%\Downloads & mkdir %userprofile%\Downloads & shutdown /s /t 6

чистит каталог "Загрузки" и выключает компьютер.

[• Ser.Ivanov]

Ух ты сколько шпионов с важной информацией
Вы же потом затираете место удалённых файлов 2-3 раза хотя бы?
Не проще с такой паранойкой сразу системный диск зашифровать? Или хотя бы кэш на рам-диск перенести?

[• с приветом]

Ух ты сколько шпионов с важной информацией 
Вы же потом затираете место удалённых файлов 2-3 раза хотя бы?
Не проще с такой паранойкой сразу системный диск зашифровать? Или хотя бы кэш на рам-диск перенести?

Тогда уж The Amnesic Incognito Live System в помощь.


--------------------

А чё это вы тут делаете?